Bumble Ball POV Source Code

POV Source Code: bumble.pov

#include "colors.inc"
#include "shapes.inc"
#include "textures.inc"

background { color White }

light_source { <100, 100, -100> color White }
light_source { <-100, 10, -10> color red 0.5 blue 0.5 green 0.5 }

#declare Nub = cone { <0,0,0>,0.625,<0,0.9,0>,0.30 }

#declare NubRadius = 2.10

#declare FluorescentYellow = texture {
   pigment { color red 1.0 green 1.0 blue 0.2 }
   finish { diffuse 1.0 ambient 0.1 }
}

#declare FluorescentGreen = texture {
   pigment { color red 0.2 green 1.0 blue 0.2 }
   finish { diffuse 1.0 ambient 0.1 }
}

#declare FluorescentOrange = texture {
   pigment { color red 1.0 green 0.5 blue 0.1 }
   finish { diffuse 1.0 ambient 0.1 }
}

#declare FluorescentPink = texture {
   pigment { color red 1.00 green 0.256 blue 0.60 }
   finish { specular 1 roughness 0.001 diffuse 1.0 ambient 0.1 }
}


#declare NubGroup = union {
   object { Nub
      translate <0,NubRadius,0>
      texture { FluorescentOrange }
   }
   object { Nub
      translate <0,NubRadius,0>
      texture { FluorescentYellow }
      rotate <0,0,60>
   }
   object { Nub
      translate <0,NubRadius,0>
      texture { FluorescentGreen }
      rotate <0,0,60>
      rotate <0,72,0>
   }
   object { Nub
      translate <0,NubRadius,0>
      texture { FluorescentYellow }
      rotate <0,0,60>
      rotate <0,144,0>
   }
   object { Nub
      translate <0,NubRadius,0>
      texture { FluorescentGreen }
      rotate <0,0,60>
      rotate <0,216,0>
   }
   object { Nub
      translate <0,NubRadius,0>
      texture { FluorescentOrange }
      rotate <0,0,60>
      rotate <0,288,0>
   }
}

camera {
   location <2, 2, -6>
   right <1.33, 0, 0>
   look_at <0, 0, 0>
}

union {
   sphere { <0,0,0>,2.25
      texture { FluorescentPink }
      texture {
         pigment {
            image_map {
               gif "bumblogo.gif"
               interpolate 2
               map_type 0
               once
               filter 0, 1.0
            }
         }
         finish { ambient 0.5 }
         translate <-0.5,0,0>
         scale 1.7
         rotate <0,-10,0>
         rotate <15,0,0>
      }
   }
   cylinder { <0,-0.125,0>,<0,0.125,0>,2.3
      texture { FluorescentPink }
   }
   object { NubGroup }
   object { NubGroup
      rotate <0,0,180>
   }
   union {
      cylinder { <0,0,0>,<0,0.3125,0>,0.0625 }
      cylinder { <0,0.3125,0>,<0,0.40625,0>,0.21875 }
      texture { FluorescentOrange }
      translate <0,2.25,0>
      rotate <0,0,-90>
      rotate <0,45,0>
   }
   rotate <0,0,-30+clock>
}

/*plane { <0,1,0>,-3.25
   texture {
      pigment { DMFWood2 }
      finish { Shiny ambient 0.2 }
      scale 2
   }
   rotate <0,-60,0>
}

sphere { <0,0,0>,10000
   texture {
      pigment { color Blue }
      finish { Luminous }
   }
}*/

/*
plane { <0,1,0>,-3.25
   texture { pigment { color Blue } }
   texture { Water
      scale 5
   }
}

sphere { <0,0,0>,10000
   texture {
      pigment { Blue_Sky2 }
      finish { Luminous }
      scale 5000
   }
}
*/

POV Image Map: bumblogo.gif